Halcon的一维条码解码步骤和解码技巧

一、图像预处理和条码增强
对比度太低：scale_image（或使用外部程序scale_image_range），增强图像的对比度。

图像模糊：emphasize锐化图像，使条码看起来更清晰。

深色背景上读取浅色条码：invert_image反转图像。

二、解码涉及的主要算子
read_image ：读图

create_bar_code_model ：创建条码模型

find_bar_code ：查找条码

clear_bar_code_model ：清除条码模型

如果条码非常简单，那么顺次执行上面4个算子就可以完成解码了。另外还有几个算子也很重要：

set_bar_code_param ：设置解码时的参数

decode_bar_code_rectangle2 ：在指定的矩形区域内解码

get_bar_code_param ：获取解码时的参数（如果没有设置过，则获得的是默认值）

get_bar_code_result ：获得解码后的结果，例如可以获得条码的类型（Code 128、Code 39等等）

get_bar_code_object ：获得解码时的一些对象，例如可以获得解码后的条码区域

三、提高解码能力的其他措施
如果条码图像预处理以后，仍旧解码困难或者解码率不高，那么可以通过以下措施进一步提高解码能力：

1、如果整张图信息太多，则可以先把条码区域挖出来，使用reduce_domain和crop_domain算子，这样不仅可以降低解码难度，还可以减少解码时间。也可使用decode_bar_code_rectangle2在指定的矩形区域内解码。

2、可以尝试把条码图像转正再解码。（这种操作未经严格验证，不知道是否可以有效提高解码率）

3、当条码很密或者很小的时候，可以尝试用zoom_image_factor放大了条码图像。

4、find_bar_code中将“CodeType”设置为“auto”可以读取多种类型的条码，但是会增加运行时间，且可能会降低解码的可靠性。最好只扫描预知的条形码类型。

5、如果对于质量很差的条码，可以模拟日常手机扫码时的操作，即多次改变曝光，多次解码的方式，参考文章：

https://www.cnblogs.com/xh6300/p/9809692.html

6、通过set_bar_code_param算子设置解码时的参数，可以有效提高解码能力。（见下文）

四、set_bar_code_param算子的参数解析

'element_size_min'	条码的最小尺寸，指条码宽度和间距，大码应设大一点，减少处理时间
'element_size_max'	条码的最大尺寸，不能过小也不能过大
'check_char'	是否验证校验位，'absent'不检查校验和，'present'检查校验和
'persistence'	设置为1，则会保留中间结果，评估条码印刷质量时会用到
'num_scanlines'	解码时所用扫描线的最大数目，设置为0表示自动确定，一般设置为2-30
'start_stop_tolerance'	容许误差值，可设置为'low'或者'high'，设置为'high'可能造成误判
'orientation'、'orientation_tol'	分别指条码的方向和方向容差，设置准确可大大提高解码效率
'element_height_min'	条码的最小高度，默认值-1表示自动推测条码高度，该参数对速度影响大
'stop_after_result_num'	设置要解码的个数，0表示全部找出，设置为2表示找到2个就不找了

 

一维码扫描示例代码

dev_set_draw ('margin')
dev_set_line_width (2)

path := 'BarCode'

dev_open_window (0, 0, 500, 500, 'black', WindowHandle)

list_files (path, ['files','follow_links'], ImageFiles)
tuple_regexp_select (ImageFiles, ['\\.(tif|tiff|gif|bmp|jpg|jpeg|jp2|png|pcx|pgm|ppm|pbm|xwd|ima|hobj)$','ignore_case'], ImageFiles)
for Index := 0 to |ImageFiles| - 1 by 1
    read_image (Image, ImageFiles[Index])
   
    *优化条码图像
    emphasize (Image, Image, 3, 3, 1)
    scale_image_range (Image, ImageScaled, 30, 220)

    *创建条码模型
    create_bar_code_model ([], [], BarCodeHandle)

    *设置解码参数
    set_bar_code_param (BarCodeHandle, 'element_size_min', 4)
    set_bar_code_param (BarCodeHandle, 'element_size_max',32)
    set_bar_code_param (BarCodeHandle,'check_char','present')
    set_bar_code_param (BarCodeHandle, 'persistence', 1)
    set_bar_code_param (BarCodeHandle, 'num_scanlines', 10)
    set_bar_code_param (BarCodeHandle, 'start_stop_tolerance', 'high')
    set_bar_code_param (BarCodeHandle, 'orientation', 0)
    set_bar_code_param (BarCodeHandle, 'orientation_tol', 20)
    set_bar_code_param (BarCodeHandle, 'element_height_min', 100)
    set_bar_code_param (BarCodeHandle, 'stop_after_result_num', 0)


    *解码
    **decode_bar_code_rectangle2的解码能力似乎不如find_bar_code，漏掉了一个码
*     smallest_rectangle2 (Rectangle, Row1, Column1, Phi, Length1, Length2)
*     decode_bar_code_rectangle2 (Image, BarCodeHandle, ['Code 128','Code 39'], Row1, Column1, Phi, Length1, Length2, DecodedDataStrings)

    * ['Code 128','Code 39']这么写表示既可以解128码，也可以解39码
    find_bar_code (Image, SymbolRegions1, BarCodeHandle, ['Code 128','Code 39'], BarCodeStrings)

    get_bar_code_param (BarCodeHandle, 'element_size_min', GenParamValues)
    get_bar_code_object (BarCodeObjects, BarCodeHandle, 'all', 'symbol_regions')
    get_bar_code_result (BarCodeHandle, 'all', 'decoded_types', BarCodeResults)
    get_bar_code_result (BarCodeHandle, 0, 'quality_isoiec15416', Quality)
    disp_message (WindowHandle, BarCodeResults + '码：' + BarCodeStrings, 'image', 20, 20, 'black', 'true')

    *清除条码模型
    clear_bar_code_model (BarCodeHandle)
    stop ()
endfor

扫描结果

 

 

Halcon的二维码解码步骤和解码技巧

一、二维码简介

1 . 类型多样，常见的有QR Code二维码、 Data Matrix二维码等。

2．高密度编码，信息容量大。

3．容错能力强，具有纠错功能：二维码因穿孔、污损等引起局部损坏时，照样可以正确得到识读，损毁面积达50％仍可恢复信息。 

4．译码可靠性高：它比普通条码译码错误率百万分之二要低得多，误码率不超过千万分之一。 

5．可引入加密措施：保密性、防伪性好。 

二、图像预处理和二维码增强

对比度太低：scale_image（或使用外部程序scale_image_range），增强图像的对比度。

图像模糊：emphasize锐化图像，使二维码看起来更清晰。

三、解码涉及的主要算子

read_image ：读图

create_data_code_2d_model ：创建二维码模型

find_data_code_2d ：查找二维码

clear_data_code_2d_model ：清除二维码模型

还有几个算子也值得注意一下：

set_data_code_2d_param ：设置解码时的参数

get_data_code_2d_param ：获取解码时的参数（如果没有设置过，则获得的是默认值）

get_data_code_2d_results ：获得解码后的一些结果

四、提高解码能力的其他措施

如果二维码图像预处理以后，仍旧解码困难或者解码率不高，那么可以通过以下措施进一步提高解码能力：

1、如果整张图信息太多，则可以先把二维码区域挖出来，使用reduce_domain和crop_domain算子，这样不仅可以降低解码难度，还可以减少解码时间。

2、当二维码很小的时候，可以尝试用zoom_image_factor放大了二维码图像。

3、create_data_code_2d_model ('QR Code', [], [], DataCodeHandleQR)

创建模型时，[ ]中不填内容，实际默认属性名是‘default_parameters’，默认属性值是‘standard_recognition’。

如果想大幅度提高解码成功率，可以将属性值置为‘enhanced_recognition’或者‘maximum_recognition’。注意：解码能力越强，解码时间越长。

4、find_data_code_2d (Image, SymbolXLDs, DataCodeHandle, 'train', 'all', ResultHandles, DecodedDataStrings) 

该算子中的GenParamNames、GenParamValues默认是空的，就是说直接找，找不到拉倒。如果是'train'，就是一面找一面调整模板参数。

默认情况下，它只会最多找到1个二维码。如果想找出更多的二维码（例如3个），可以这样：

find_data_code_2d (Image2, SymbolXLDs, DataCodeHandle, 'stop_after_result_num', 3, ResultHandles, DecodedDataStrings)

5、如果对于质量很差的二维码，可以模拟日常手机扫码时的操作，即多次改变曝光，多次解码的方式，参考文章：

https://www.cnblogs.com/xh6300/p/9809692.html

6、通过set_data_code_2d_param算子设置解码时的参数，可以有效提高解码能力。（见下文）

五、set_data_code_2d_param算子的参数解析

'default_parameters'	‘standard_recognition’、‘enhanced_recognition’、‘maximum_recognition’
'timeout'	延迟时间，超过这个时间还没找到就不找了
'polarity'	极性，可设置'dark_on_light'（白色背景黑码）或者'light_on_dark'
'module_size_min'	最小码粒像素大小，码粒大小指的二维码中矩形颗粒的宽度（存疑）
'module_size_max'	最大码粒像素大小

 

 

二维码扫描示例代码

*输入参数：
*coding:='utf8' 编码
*path:=图片路径
*timeOut:=超时时间
*count:=检测数量
*输出参数：
*EmptyObject XLD轮廓
*Runtime 耗时
*type_and_data 类型与数据

coding:='utf8'
path := 'H:/kevin/halcon_workspace/CodeData/image/QRCode/image7'
timeOut := 0
count :=100
scal := 1
type_and_data:=[]
num:=0
gen_empty_obj (EmptyObject)
set_system ('filename_encoding', coding)
read_image (Image, path)

get_image_size(Image, Width, Height)

dev_open_window (0, 0, Width, Height, 'black', WindowHandle)

zoom_image_factor(Image,ZoomImage,0.125,0.125,'bilinear')
rgb1_to_gray (ZoomImage, GrayImage)

dev_display (GrayImage)

min_max_gray (GrayImage, GrayImage, 0, Min, Max, Range)
Mult := 255.0 / (Max - Min)
Add := -Mult * Min
scale_image (GrayImage, GrayImage1, Mult, Add)
dev_display (GrayImage1)
stop()

_codeMode:=['Aztec Code', 'Data Matrix ECC 200', 'GS1 Aztec Code', 'GS1 DataMatrix', 'GS1 QR Code', 'Micro QR Code', 'PDF417', 'QR Code']
*创建二维码数据class模型
count_seconds (T1)

create_data_code_2d_model ('QR Code','default_parameters', 'maximum_recognition',DataCodeHandle)

*设置超时时间
set_data_code_2d_param (DataCodeHandle, 'timeout', timeOut)

*因为某些二维码模型没有这个属性，会报错所以try以下
try
    *set_data_code_2d_param (DataCodeHandle, 'strict_quiet_zone', 'yes')
catch (Exception)
   
endtry
*开始识别 
find_data_code_2d (GrayImage,SymbolXLDs,DataCodeHandle, 'stop_after_result_num', count,ResultHandles, DecodedDataStrings)
dev_display (Image)
dev_display (SymbolXLDs)
count_obj (SymbolXLDs, Number)
if (Number)
    *存类型
    type_and_data[num]:= 'QR Code'
    num:=num+1
    for j := 0 to Number-1 by 1
        *存数据
        type_and_data[num]:=DecodedDataStrings[j]
        num:=num+1
        
        select_obj (SymbolXLDs, ObjectSelected, j+1)
        get_contour_xld (ObjectSelected, Row, Col)

        set_tposition(WindowHandle,(Row[0]-10),Col[0])
        write_string (WindowHandle, DecodedDataStrings[j])
        *保存XLD轮廓
        concat_obj (EmptyObject, ObjectSelected, EmptyObject)

endfor
endif

*清除识别缓存
clear_data_code_2d_model(DataCodeHandle) 

count_seconds (T2)
Runtime:=T2-T1
return ()

扫码结果: